Finding refugee children who come to Norway with or without parents

The example below shows how to find out whether refugee children who are granted residence in Norway come together with their parents or not.

You use the date of residence and compare it with the parents' date of residence. If the year of first stay in Norway is the same, the child is considered to be coming together with the respective parents.

Furthermore, information on the reason for immigration is used to find refugee status, country of birth to find out where you come from, and age at first residence to limit to the age group 0-17 years.

In this specific example, we look at refugee children who come from Bosnia.

 textblock
Find out if a child (0-17 years old) came as a refugee with or without parents. This example looks at refugees from Bosnia.
endblock

require no.ssb.fdb:30 as db

create-dataset refugee_children
import db/BEFOLKNING_INNGRUNN1 as immigration_reason
import db/BEFOLKNING_FODELAND as birth_country
import db/BEFOLKNING_INNALDER as immigration_age
tabulate immigration_reason if birth_country == '155'
summarize immigration_age if immigration_reason == 'FLU' & birth_country == '155'
keep if immigration_reason == 'FLU' & birth_country == '155' & inrange(immigration_age,0,17)

import db/BEFOLKNING_FAR_FNR as fatherid
import db/BEFOLKNING_MOR_FNR as motherid
import db/BEFOLKNING_FORSTDATO as first_residence
replace first_residence = int(first_residence / 10000)
histogram first_residence, discrete
//Comment: Most got residence in 1993 or 1994


create-dataset refugee_parents
import db/BEFOLKNING_INNGRUNN1 as immigration_reason
keep if immigration_reason == 'FLU'

import db/BEFOLKNING_FORSTDATO as first_residence_father
replace first_residence_father = int(first_residence_father / 10000)
clone-variables first_residence_father -> first_residence_mother

merge first_residence_father into refugee_children on fatherid
merge first_residence_mother into refugee_children on motherid


use refugee_children
histogram first_residence_father, discrete
histogram first_residence_mother, discrete
tabulate first_residence, missing
tabulate first_residence_father, missing
tabulate first_residence_mother, missing

generate came_with_father = first_residence == first_residence_father
generate came_with_mother = first_residence == first_residence_mother
generate came_with_mother_and_father = came_with_father & came_with_mother
generate came_with_mother_or_father = came_with_father | came_with_mother

tabulate came_with_father, cellpct freq
tabulate came_with_mother, cellpct freq
tabulate came_with_mother_and_father, cellpct freq
tabulate came_with_mother_or_father, cellpct freq
piechart came_with_mother_or_father
//Comment: Only 4% of refugee children from Bosnia came to Norway without parents. The rest came with either mother or father (or both). Most of those who came with at least one parent came with mother.